Lotus Domino Designer 7 ヘルプ

式言語

例:@Compare
1 このアクションはリストを値「N」と比較し、その結果を表示します。Boston と Moscow の結果は -1 (N より小さい)、Tokyo は 1 (N より大きい)、n と N は 0 です。

list := "Boston" :"Tokyo" :"Moscow" :"N" :"n";
result := @text(@compare(list; "N"; [CaseInsensitive]));
@Prompt([OKCANCELLIST] :[NOSORT];
"Result"; ""; ""; list + " (" + result + ")")

2 次の計算結果フィールド式は、2 つの複数値フィールド [Name1] と [Name2] を比較し、結果を値として通知します。文字列は結果の数値で置き換えられます。

@If(Names1 = "" | Names2 = ""; ""; @do(
comp1 := @Compare(Names1; Names2;
[CASEINSENSITIVE] :[ACCENTINSENSITIVE]);
comp2 := @Replace(@Text(comp1); "-1" :"0" :"1";
" is less than " :" is equal to " :" is greater than ");
Names1 + comp2 + Names2))

3 次の計算結果フィールド式は Column2 という複数値フィールドに指定されるもので、Column1 を A と Z と比較し、値の先頭が英字範囲内にあるかどうかを調べます。Column1 の値が範囲外であるときは、文字列が Column2 に通知されます。

@If(Column1 = ""; ""; @Do(
Low1 := @Compare(Column1; "A"; [CASEINSENSITIVE]);
High1 := @Compare(Column1; "Z"; [CASEINSENSITIVE]);
Low2 := @Replace(@Text(Low1); "-1" :"0" :"1"; "Does not start with alpha" :"" : "");
High2 := @Replace(@Text(High1); "-1" : "0" : "1"; "" : "" : "Does not start with alpha");
Low2 + High2))

4 この式は [sailboats] フィールドの文字列リストから、a、b、または c で始まる要素をすべて取り出します。

@For(n:=1;n <= @Elements(sailboats);n := n+1;
FIELD result := @If(n=1;@If(@Compare(sailboats[n];"d";[CASEINSENSITIVE])=-1;
sailboats[n];"");@If(@Compare(sailboats[n];"d";[CASEINSENSITIVE])=-1;
result:(sailboats[n]);result)));
result

[sailboats] フィールドの内容が "Hunter":"C&C":"Pearson":"Contessa":"Bristol" のとき、この式は "C&C;Contessa;Bristol" を返します。

関連項目

用語集

用語集