Lotus Domino Designer 6.5.1 ヘルプ - 例:外部データベースからデータを取り出す

LOTUS CONNECTORS

例:外部データベースからデータを取り出す
1 次のエージェントは新しい ODBCConnection、ODBCQuery、および ODBCResultSet オブジェクトを宣言し、データソースに接続し、ODBCQuery オブジェクトと ODBCResultSet オブジェクトを ODBCQuery オブジェクトに関連付け、検索を指定して実行し、結果セットを最初の行から最後の行まで順番に調べます。

Uselsx "*LSXODBC"

Sub Initialize
Dim con As New ODBCConnection
Dim qry As New ODBCQuery
Dim result As New ODBCResultSet
Dim firstName As String
Dim lastName As String
Dim msg As String
If Not con.ConnectTo("ATDB") Then
Messagebox "Could not connect to ATDB",, _
"Error connecting"
Exit Sub
End If
Set qry.Connection = con
Set result.Query = qry
qry.SQL = "SELECT * FROM STUDENTS ORDER BY LASTNAME"
result.Execute
msg = "Student names:"& Chr(10)
If result.IsResultSetAvailable Then
Do
result.NextRow
firstName = result.GetValue("FIRSTNAME")
lastName = result.GetValue("LASTNAME")
msg = msg & Chr(10) & firstName & " " _
& lastName
Loop Until result.IsEndOfData
result.Close(DB_CLOSE)
Else
Messagebox "No data retrieved for STUDENTS",, _
"No data"
Exit Sub
End If
Messagebox msg,, "Student Names"
con.Disconnect
End Sub

2 次のスクリプトは、ユーザーが「Parts」文書の [Part_Number] フィールドから出たときに実行されます。スクリプトは SELECT ステートメントの WHERE 節の [Part_Number] の値を使って検索を実行し、取り出されたレコードの値に基づいて [PartName]、[Cost]、[Description] フィールドに値を入れます。

Sub Exiting(Source As Field)
Dim con As New ODBCConnection
Dim qry As New ODBCQuery
Dim res As New ODBCResultSet
Dim ws As New Notesuiworkspace
Dim uidoc As Notesuidocument
Set uidoc = ws.CurrentDocument
If con.ConnectTo("PARTS") Then
Set qry.Connection = con
qry.SQL = _
"select * from PARTS where PART_NO = '" + _
uidoc.FieldGetText("Part_Number") + "'"
Set res.Query = qry
res.Execute
If res.IsResultSetAvailable Then
res.FirstRow
Call uidoc.FieldSetText("Part_Number", _
res.GetValue("PART_NO"))
Call uidoc.FieldSetText("Part_Name", _
res.GetValue("PART_NAME"))
Call uidoc.FieldSetText("Price", _
res.GetValue("COST"))
Call uidoc.FieldSetText("Description", _
res.GetValue("DESCRIPTION"))
Else
Messagebox("No information found for " + _
uidoc.FieldGetText("Part_Number") )
End If
res.Close(DB_CLOSE)
con.Disconnect
Else
Messagebox("Could not connect to database server")
End If
End Sub

3 次のエージェントは、実行前に SQL 検索にパラメータを設定します。NumParameters はループの上限値として使用され、GetParameterName は各パラメータ値の入力応答に使われます。

Sub Initialize
Dim con As New ODBCConnection
Dim qry As New ODBCQuery
Dim result As New ODBCResultSet
Dim inputParameter As String
Dim firstName As String
Dim lastName As String
Dim msg As String
Set qry.Connection = con
Set result.Query = qry
con.ConnectTo("ATDB")
qry.SQL = "SELECT * FROM STUDENTS" & _
" WHERE FIRSTNAME = ?firstName?AND LASTNAME = _
?lastName?"
For i = 1 To result.NumParameters
inputParameter = _
Inputbox$(result.GetParameterName(i), _
"Parameter " & i)
Call result.SetParameter(i, "'" _
& inputParameter & "'")
Next
result.Execute
msg = "Student name:" & Chr(10)
If result.IsResultSetAvailable Then
result.NextRow
studentNo = result.GetValue _
("STUDENT_NO", studentNo)
firstName = result.GetValue _
("FIRSTNAME", firstName)
lastName = result.GetValue("LASTNAME", lastName)
msg = msg & Chr(10) & studentNo & " " & _
firstName & " " & lastName
Else
Messagebox "Cannot get result set"
Exit Sub
End If
Messagebox msg,, "Student name"
con.Disconnect
End Sub

関連項目

用語集

用語集