GetOIDCAccessToken (NotesSession)

これは、IDファイルによって識別および認証された現在のユーザーに対して、Domino OIDCプロバイダーからアクセストークンを取得するために使用されます。

注記：このメソッドは、バージョン 14.5.1 から使用できます。

定義位置

NotesSession

構文

token$ = session.GetOIDCAccessToken ( server$, clientid$, issuer$, resource$, scope$)

パラメータ

サーバー$
文字列。接続先のDominoサーバーの名前。

クライアントID$
文字列。OAuthアプリケーションのクライアントID。

発行者$
文字列。発行者（空文字列の場合はDomino OIDCプロバイダー）。

リソース$
文字列。要求されたリソース（空文字列の場合は、クライアント用に最初に設定されたオーディエンス）

スコープ
文字列。要求されたスコープ（空文字列の場合はクライアント用に設定されたスコープ）

戻り値

トークン$
文字列。アクセストークン。

使用例

このサンプルコードは、OIDCアクセストークンを取得するためのシンプルなスクリプトを示しています。

Option Declare

Sub Initialize

Dim Session As New NotesSession
Dim Server As String
Dim ClientID As String
Dim Issuer As String
Dim Resource As String
Dim Scopes As String
Dim Token As String

On Error GoTo error_handler

Server = "oidc.example.org"
ClientID = "oidc-example-org"
Issuer = "https://oidc.example.org/auth/protocol/oidc"
Resource = ""
Scopes = ""

MessageBox "User Name: "& session.UserName

Token = session.getOIDCAccessToken (Server, ClientID, Issuer, Resource, Scopes)

MessageBox "OIDC Token: "& Token
Exit Sub

error_handler:

MessageBox "Error " & Err & ": " & Error$
Exit Sub

End Sub

このサンプルは、リソースを要求するエンドツーエンドのプロセスを示しています。

Option Public
Option Declare


Sub Initialize

On Error GoTo error_handler

Dim session As New NotesSession
Dim http As NotesHTTPRequest

Dim Server As String
Dim ClientID As String
Dim Issuer As String
Dim Resource As String
Dim Scopes As String
Dim Token As String
Dim Url As String
Dim Response As String

' --- OIDC configuration ---
Server = "oidc.example.org"
ClientID = "oidc-example-org"
Issuer = "https://oidc.example.org/auth/protocol/oidc"
Resource = ""
Scopes = ""

MessageBox "User Name: " & session.UserName

' --- Get OIDC access token ---
Token = session.GetOIDCAccessToken(Server, ClientID, Issuer, Resource, Scopes)

If Token = "" Then
Error 1000, "No OIDC access token returned"
End If

Url = "https://domino.example.org/sampleDB.nsf"

Set http = session.CreateHTTPRequest()

http.SetHeaderField "Authorization", "Bearer " & Token
http.SetHeaderField "User-Agent", "HCL Notes 14.5.1 OIDC Test"

Response = http.Get(Url)

MessageBox "HTTP Status: " & http.ResponseCode & Chr(10) & Chr(10) & "Response:" & Chr(10) & Response

Exit Sub

error_handler:

MessageBox "Error " & Err & ": " & Error$
Exit Sub

End Sub