NotesJSONObject (LotusScript)

JSON オブジェクトを表します。

包含関係

包含元: NotesJSONNavigator

プロパティ

Size プロパティ
JSON オブジェクト内の要素の数。

メソッド

GetElementByName メソッド
指定された名前の JSON オブジェクトを返します。

GetFirstElement メソッド 
JSON オブジェクトの最初の要素を返します。

GetNextElement メソッド 
JSON オブジェクトの次の要素を返します。

GetNthElement メソッド
指定されたインデックスの JSON オブジェクトから要素を取得します。

AppendElement メソッド
NotesJSONElement を NotesJSONObject に追加します。

AppendArray メソッド
NotesJSONArray を NotesJSONObject に追加します。

AppendObject メソッド
NotesJSONObject を NotesJSONObject に追加します。

Copy メソッド
NotesJSONObjectからNotesJSONObjectへ値をコピーします。

Size プロパティ

JSON オブジェクト内の要素の数。

データ型

Long

GetElementByName メソッド

指定された名前の JSON オブジェクトを返します。

構文

Set el = obj.Getelementbyname("name")

パラメーター

name

String

戻り値

JSON オブジェクト

例

次の例では、"object1" という名前のオブジェクトを取得し、"object1 = inner1:innerval1" という文字列をメッセージボックスに表示します。

Set jsnav = s.CreateJSONNavigator(|{"objects":{"object1": {"inner1":"innerval1"},"object2": {"inner2":"innverval2"}, "object3": {"inner3":"innverval3"}}}|)
Set el = jsnav.Getfirstelement()
Set obj = el.value
Set el = obj.Getelementbyname("object1")
Set el = el.value.GetelementByName("inner1")
MsgBox "object1 = " & CStr(el.Name) & ":" & CStr(el.Value)

GetFirstElement メソッド

JSON オブジェクトの最初の要素を返します。

構文

Set el = obj.GetFirstElement()

パラメータ

なし

戻り値

オブジェクト内の最初の NotesJSONElement

例

次の例では、「object1」という名前のオブジェクトを取得し、「First object = inner1:innerval1」という文字列をメッセージボックスで表示します。

Set jsnav = s.CreateJSONNavigator(|{"objects":{"object1": {"inner1":"innerval1"},"object2": {"inner2":"innverval2"}, "object3": {"inner3":"innverval3"}}}|)
Set el = jsnav.Getfirstelement()
Set obj = el.Value
Set el = obj.Getfirstelement()
Set el = el.value.GetelementByName("inner1")
MsgBox "First object = " & CStr(el.Name) & ":" & CStr(el.Value)

GetNextElement メソッド

JSON オブジェクトの次の要素を返します。

構文

Set el = obj.GetNextlement()

パラメータ

なし

戻り値

オブジェクト内の次の NotesJSONElement

例

次の例では、「object2」という名前のオブジェクトを取得し、「Next object = inner2:innerval2」という文字列をメッセージボックスで表示します。

Set jsnav = s.CreateJSONNavigator(|{"objects":{"object1": {"inner1":"innerval1"},"object2": {"inner2":"innverval2"}, "object3": {"inner3":"innverval3"}}}|)
Set el = jsnav.Getfirstelement()
Set obj = el.Value
Set el = obj.Getfirstelement()
Set el = obj.GetNextelement()
Set el = el.value.GetelementByName("inner2")
MsgBox "Next object = " & CStr(el.Name) & ":" & CStr(el.Value)

GetNthElement メソッド

指定されたインデックスの JSON オブジェクトから要素を取得します。

構文

Set el = obj.Getnthelement(Index)

パラメータ

Index

Integer

1 をベースとした要素の位置を示すインデックス値

戻り値

オブジェクト内の次の NotesJSONElement

例

次の例では、「object3」という名前のオブジェクトを取得し、"Nth (3) object = inner3:innerval3」という文字列をメッセージボックスで表示します。

Set jsnav = s.CreateJSONNavigator(|{"objects":{"object1": {"inner1":"innerval1"},"object2": {"inner2":"innverval2"}, "object3": {"inner3":"innverval3"}}}|)
Set el = jsnav.Getfirstelement()
Set obj = el.Value
Set el = obj.GetNthElement(3)
Set obj = el.value
Set el = obj.GetElementByName("inner3")
MsgBox "Nth (3) object = " & CStr(el.Name) & ":" & CStr(el.Value)

AppendElement メソッド

NotesJSONElement を NotesJSONObject に追加します。

パラメータ

value

Variant。NotesJSONObject に追加する値。許可される型は、String、Integer、Long、 Double、Boolean

name

String。要素の名前。

戻り値

NotesJSONObject に追加された NotesJSONElement を返します。

例

「numberproperty」という名前の NotesJSONElement を NotesJSONObject に追加します。

Dim session As New NotesSession()
Dim jsnav As NotesJSONNavigator
Dim el As NotesJSONElement
Dim object As NotesJSONObject
		
Set jsnav = session.createJSONNavigator("")
Set object = jsnav.appendObject("myobject")
Set el = object.appendElement(3, "numberproperty")

Result: {"myobject":{"numberproperty":3}}

AppendArray メソッド

NotesJSONArray を NotesJSONObject に追加します。

パラメータ

name

String。配列の名前。

戻り値

NotesJSONObject に追加された NotesJSONArray を返します。

例

3 つの要素を含む "myarray" という名前の配列を NotesJSONObject に追加します。

Dim session As New NotesSession()
Dim jsnav As NotesJSONNavigator
Dim arr As NotesJSONArray
Dim object As NotesJSONObject
Set jsnav = session.createJSONNavigator("")
Set object = jsnav.appendObject("myobject")
Set arr = object.appendArray("myarray")
Call arr.appendElement(1)
Call arr.appendElement(2)
Call arr.appendElement(3)

Output: {"myobject":{"myarray":[1,2,3]}}

AppendObject メソッド

NotesJSONObject を NotesJSONObject に追加します。

パラメータ

name

String。オブジェクトの名前。

戻り値

NotesJSONObject に追加された NotesJSONObject を返します。

例

「myobject」という名前のオブジェクトを NotesJSONObject に追加します。

Dim session As New NotesSession()
Dim jsnav As NotesJSONNavigator
Dim nestedObject As NotesJSONObject
Dim object As NotesJSONObject
Set jsnav = session.createJSONNavigator("")
Set object = jsnav.appendObject("myobject")
Set nestedObject = object.appendObject("nestedObject")
Call nestedObject.appendElement("value1", "prop1")
Call nestedObject.appendElement("value2", "prop2")

Result: {"myobject":{"nestedObject":{"prop1":"value1","prop2":"value2"}}}